尝试做一个最简单的加法器验证系统

// DUT模块
module dut(
    input  logic [7:0] a,
    input  logic [7:0] b,
    input  logic       cin,
    output logic [7:0] sum,
    output logic       cout
);
    assign {cout, sum} = a + b + cin;
endmodule

// 接口定义
interface dut_if;
    logic [7:0] a;
    logic [7:0] b;
    logic       cin;
    logic [7:0] sum;
    logic       cout;

    modport tb (
        output a, b, cin,
        input  sum, cout
    );

    modport dut (
        input  a, b, cin,
        output sum, cout
    );
endinterface

// transaction类
class transaction;
    rand bit [7:0] a;
    rand bit [7:0] b;
    rand bit       cin;

    bit      [7:0] sum;
    bit            cout;
    bit      [7:0] expected_sum;
    bit            expected_cout;

    constraint c_valid {
        a inside {[0:255]};
        b inside {[0:255]};
        cin inside {[0:1]};
    }

    function void calculate_expected();
        {expected_cout, expected_sum} = a + b + cin;
    endfunction

    function bit compare();
        return (sum == expected_sum) && (cout == expected_cout);
    endfunction

    function void display();
        $display("a = %h, b = %h, cin = %b | Expected: sum = %h, cout = %b | Actual: sum = %h, cout = %b", 
                 a, b, cin, expected_sum, expected_cout, sum, cout);
    endfunction
endclass

// generator类
class generator;
    mailbox #(transaction) gen2drv;

    function new(mailbox #(transaction) gen2drv_new);
        if(gen2drv_new == null) begin
            $display("%0t -> generator : ERROR -> gen2drv is null", $time);
            $finish;
        end else begin
            this.gen2drv = gen2drv_new;
        end
    endfunction

    task run(int num_tr = 400);
        transaction tr;
        repeat(num_tr) begin
            tr = new();
            assert(tr.randomize()) else $error("Randomization failed");
            tr.calculate_expected(); // 计算预期输出
            $display("%0t -> generator : Generated new transaction", $time);
            tr.display();
            gen2drv.put(tr);
        end
    endtask
endclass

// driver类
class driver;
    virtual dut_if.tb intf;
    mailbox #(transaction) gen2drv;

    function new(virtual dut_if.tb intf, mailbox #(transaction) gen2drv_new);
        this.intf = intf;
        if(gen2drv_new == null) begin
            $display("%0t -> driver : ERROR -> gen2drv is null", $time);
            $finish;
        end
        else
            this.gen2drv = gen2drv_new;
    endfunction 

    task run();
        transaction tr;

        forever begin
            gen2drv.get(tr);
            intf.a   = tr.a;
            intf.b   = tr.b;
            intf.cin = tr.cin;

            #1; // 给DUT一个小的延迟来稳定输出
            tr.sum = intf.sum;
            tr.cout = intf.cout;
            
            $display("%0t -> driver : Received DUT output", $time);
            tr.display();
        end
    endtask
endclass

// Monitor类
class monitor;
    virtual dut_if.dut intf;
    mailbox #(transaction) mon2sb;

    function new(virtual dut_if.dut intf, mailbox #(transaction) mon2sb_new);
        this.intf = intf;
        if(mon2sb_new == null) begin
            $display("%0t -> monitor : ERROR -> mon2sb is null", $time);
            $finish;
        end else begin
            this.mon2sb = mon2sb_new;
        end
    endfunction

    task run();
        transaction tr;
        forever begin
            tr = new();
            #1; // 等待DUT稳定输出
            tr.a   = intf.a;
            tr.b   = intf.b;
            tr.cin = intf.cin;
            tr.sum = intf.sum;
            tr.cout = intf.cout;
            tr.calculate_expected(); // 计算期望结果

            $display("%0t -> monitor : Captured transaction", $time);
            tr.display();
            mon2sb.put(tr);
        end
    endtask
endclass

// Scoreboard类
class scoreboard;
    mailbox #(transaction) mon2sb;

    function new(mailbox #(transaction) mon2sb_new);
        if(mon2sb_new == null) begin
            $display("%0t -> scoreboard : ERROR -> mon2sb is null", $time);
            $finish;
        end else begin
            this.mon2sb = mon2sb_new;
        end
    endfunction

    task run();
        transaction tr;
        forever begin
            mon2sb.get(tr);
            if (tr.compare()) begin
                $display("%0t -> scoreboard : PASS", $time);
            end else begin
                $display("%0t -> scoreboard : FAIL", $time);
            end
            tr.display();
        end
    endtask
endclass

// Environment类
class environment;
    generator gen;
    driver    drv;
    monitor   mon;
    scoreboard sb;
    mailbox #(transaction) gen2drv;
    mailbox #(transaction) mon2sb;
    virtual dut_if.tb vif;
    virtual dut_if.dut dif;

    function new(virtual dut_if.tb vif, virtual dut_if.dut dif);
        this.vif = vif;
        this.dif = dif;
        gen2drv = new();
        mon2sb = new();
        gen = new(gen2drv);
        drv = new(vif, gen2drv);
        mon = new(dif, mon2sb);
        sb = new(mon2sb);
    endfunction

    task run();
        fork
            gen.run();
            drv.run();
            mon.run();
            sb.run();
        join_any
    endtask
endclass

// Top模块
module top;
    dut_if intf();

    dut DUT (
        .a(intf.a),
        .b(intf.b),
        .cin(intf.cin),
        .sum(intf.sum),
        .cout(intf.cout)
    );

    initial begin
        environment env;
        env = new(intf.tb, intf.dut);
        env.run();
        #100000; // 运行一段时间后结束仿真
        $finish;
    end

    initial begin
        $dumpfile("dump.vcd");
        $dumpvars(0, top);
    end
endmodule